PRO plot2rhoctc

dir0='/u/alex/EZ_3_6_3/run/'
files=['25_02','25_0001']+'.txt'

filenames=dir0+files

ll=[0,2]

FOR i=0,N_ELEMENTS(filenames)-1 DO BEGIN
   readez,filenames[i],rhoc=rhoc,tc=tc
   rhoctc,rhoc,tc,OVER=(i GT 0),LINE=ll[i]
ENDFOR

END

;-----------------------------------------------------------------------
;ooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
;-----------------------------------------------------------------------

PRO plot2hrd

dir0='/u/alex/EZ_3_6_3/run/'
files=['25_02','25_0001']+'.txt'

filenames=dir0+files

FOR i=0,N_ELEMENTS(filenames)-1 DO BEGIN
   readez,filenames[i],teff=teff,lum=lum
   hrd,teff,lum,OVER=(i GT 0),LINE=i
ENDFOR

END

;-----------------------------------------------------------------------
;ooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
;-----------------------------------------------------------------------

PRO rhoctc,tc,rhoc, $
        XRANGE=xr, $
        YRANGE=yr, $
        OVERPLOT=over, $
        LINE=line

ltc=ALOG10(tc)
lrhoc=alog10(rhoc)

IF N_ELEMENTS(yrange) EQ 0 THEN BEGIN
   yr=[MIN(ltc),MAX(ltc)]
   yr+=0.1*(yr[1]-yr[0])*[-1,1]
ENDIF
IF N_ELEMENTS(xrange) EQ 0 THEN BEGIN
   xr=[MIN(lrhoc),MAX(lrhoc)]
   xr+=0.1*(xr[1]-xr[0])*[-1,1]
ENDIF
IF N_ELEMENTS(line) EQ 0 THEN line=0
IF N_ELEMENTS(over) EQ 0 THEN over=0

IF over EQ 0 THEN BEGIN
   PLOT,lrhoc,ltc, $
        XRANGE=xr, YRANGE=yr, $
        XS=1, YS=1, $
        YTITLE='log central temperature / K', $
        XTITLE='log central density / g cm!a-3!n', $
        LINE=line
ENDIF ELSE BEGIN     
   OPLOT,lrhoc,ltc, $
         LINE=line
ENDELSE

END


;-----------------------------------------------------------------------
;ooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
;-----------------------------------------------------------------------

PRO hrd,teff,lum, $
        XRANGE=xr, $
        YRANGE=yr, $
        OVERPLOT=over, $
        LINE=line

lteff=ALOG10(teff)
llum=alog10(lum)

IF N_ELEMENTS(yrange) EQ 0 THEN BEGIN
   yr=[MIN(llum),MAX(llum)]
   yr+=0.1*(yr[1]-yr[0])*[-1,1]
ENDIF
IF N_ELEMENTS(xrange) EQ 0 THEN BEGIN
   xr=[MAX(lteff),MIN(lteff)]
   xr+=0.1*(xr[1]-xr[0])*[-1,1]
ENDIF
IF N_ELEMENTS(line) EQ 0 THEN line=0
IF N_ELEMENTS(over) EQ 0 THEN over=0

IF over EQ 0 THEN BEGIN
   PLOT,lteff,llum, $
        XRANGE=xr, YRANGE=yr, $
        XS=1, YS=1, $
        XTITLE='log effective temperature / K', $
        YTITLE='log luminosity / solar luminosity', $
        LINE=line
ENDIF ELSE BEGIN     
   OPLOT,lteff,llum, $
         LINE=line
ENDELSE

END

;-----------------------------------------------------------------------
;ooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
;-----------------------------------------------------------------------

PRO readez,name, $
           rhoc =rhoc , $
           tc   =tc   , $
           pc   =pc   , $
           lum  =lum  , $
           teff =teff , $
           time =time , $
           dt   =dt   , $
           l_he =l_he , $
           reff =reff , $
           mass =mass , $
           m_he =m_he , $
           m_env=m_env, $
           xh1  =xh1  , $
           xhe4 =xhe4 , $
           xc12 =xc12 , $
           xn14 =xn14 , $
           xo16 =xo16 , $
           psic =psic , $
           gamc =gamc

nmax=10000L
ncol=20
a=DBLARR(nmax,ncol)
al=DBLARR(ncol)
x=''
OPENR,unit,name,/GET_LUN
n=0
WHILE (NOT EOF(unit)) DO BEGIN
   READF,unit,x
   y=STREGEX(STRMID(x,0,7),"[ ]+[1-9]+[0-9]* ",LENGTH=length)
   IF length EQ 7 THEN BEGIN
      READS,x,al
      i=round(al[0])
      a[i-1,*]=al
      n>=i
   ENDIF
ENDWHILE

a=a[0:n-1,*]

rhoc=10.D0^a[*, 1]
tc  =10.D0^a[*, 2]
pc  =10.D0^a[*, 3]
lum =10.D0^a[*, 4]
teff=10.D0^a[*, 5]
time=10.D0^a[*, 6]
dt  =10.D0^a[*, 7]
l_he=10.D0^a[*, 8]
reff=10.D0^a[*, 9]
mass      =a[*,10]
m_he      =a[*,11]
m_env     =a[*,12]
xh1       =a[*,13]
xhe4      =a[*,14]
xc12      =a[*,15]
xn14      =a[*,16]
xo16      =a[*,17]
psic      =a[*,18]
gamc      =a[*,19]

END